Saturday, 27 July 2013

I2C Communication - Interfacing Sensors - MPU6050, BMP085 & HMC5883L

There are a number of sensors with I2C interface. The I2Cdev project offers a set of libraries to work with these.  We will look at how to interface 3 such sensors(one at a time!) to our Induino R3 Board (same works for all Arudino Boards as well!) using this library.

Download the I2Cdevlib from here https://github.com/jrowberg/i2cdevlib/archive/master.zip
Extract the downloaded file and go inside the Arduino folder inside the extracted file.  This folder has a number of libraries. We will copy the 4 libraries - I2Cdev, MPU6050, BMP085 & HMC5883L. Follow the manual library installation process from here for each of these libraries.

To interface these sensors, you would need a breadboard and some wires to place and connect these sensors.

MPU6050 - 6 DOF - 3-Axis Accelerometer + 3-Axis Gyro

The MPU6050 is a motion tracking device from Invensense.  The sensor combines a 3-axis gyroscope and a 3-axis accelerometer on the same silicon die together with an onboard Digital Motion Processor™ (DMP™) capable of processing complex MotionFusion algorithms. While all this might be high tech only a limited amount of that technology is available outside the official software required to work with it. Luckily,  the I2Cdev library exposes most of the functions.  You can buy it here -> MPU 6050 Breakout Board

Download the Product Specification Sheet Here
Download the Product Register Map Here


Read this to know more about Accelerometers & Gyroscopes ->
http://www.instructables.com/id/Accelerometer-Gyro-Tutorial/

Connecting the MPU6050  ( connections are for the module above with model number GY-521 for other modules refer to the module datasheet and connect accordingly)

  • Place the MPU6050  Breakout Board on the breadboard
  • Connect the SDA pin on the MPU6050 to the SDA pin on the Induino R3
  • Connect the SCL pin on the MPU6050 to the SCL pin on the Induino R3
  • Conect the Vcc pin on the MPU6050 to 5Volts on the Induino R3
  • Connect the GND pin on the MPU6050 to the GND pin on the Induino R3
  • Connect the INT pin on the MPU6050 to digital pin 2 on the Induino R3 (this is an interrupt pin - more about this later)

Go to File->Examples->MPU6050-> and click on MPU6050_DMP6

Upload the program and watch the various values for Accelerometer / Gyro in your serial monitor. Now this program has options to configure various calculated outputs. Go through the comments and use wisely.


BMP085 - Barometric Pressure Sensor

The BMP085 is a high-precision, ultra-low power barometric pressure sensor. It can be used for a number of applications. Barometric Pressure can be used to calculate a number of factors like altitude, etc. You can buy it here -> BMP085 Breakout Board

Download the Datasheet Here
Connecting the BMP085  ( connections are for the module above with model number GY-65 for other modules refer to the module datasheet and connect accordingly)
  • Place the BMP085 Breakout Board on the breadboard
  • Connect the SDA pin on the BMP085 to the SDA pin on the Induino R3
  • Connect the SCL pin on the BMP085 to the SCL pin on the Induino R3
  • Conect the Vcc pin on the BMP085 to 5Volts on the Induino R3
  • Connect the GND pin on the BMP085 to the GND pin on the Induino R3
Go to File->Examples->BMP085-> and click on BMP085_basic

Upload the program and watch the various values for pressure in your serial monitor. These are raw values. You can further experiment by modifying the following program from http://bildr.org/ This Program works on bare I2C communication without any libraries.

/*  Induino R3 User Guide - Program 12.0 - Interfacing the GY-65 BMP085 Breakout Board with the Induino R3*/
/* Code from Bildr.org */

/*Based largely on code by  Jim Lindblom
 
 Get pressure, altitude, and temperature from the BMP085.
 Serial.print it out at 9600 baud to serial monitor.
 */

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5; 

void setup(){
  Serial.begin(9600);
  Wire.begin();
  bmp085Calibration();
}

void loop()
{
  float temperature = bmp085GetTemperature(bmp085ReadUT()); //MUST be called first
  float pressure = bmp085GetPressure(bmp085ReadUP());
  float atm = pressure / 101325; // "standard atmosphere"
  float altitude = calcAltitude(pressure); //Uncompensated caculation - in Meters 

  Serial.print("Temperature: ");
  Serial.print(temperature, 2); //display 2 decimal places
  Serial.println("deg C");

  Serial.print("Pressure: ");
  Serial.print(pressure, 0); //whole number only.
  Serial.println(" Pa");

  Serial.print("Standard Atmosphere: ");
  Serial.println(atm, 4); //display 4 decimal places

  Serial.print("Altitude: ");
  Serial.print(altitude, 2); //display 2 decimal places
  Serial.println(" M");

  Serial.println();//line break

  delay(1000); //wait a second and get values again.
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature in deg C
float bmp085GetTemperature(unsigned int ut){
  long x1, x2;

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  float temp = ((b5 + 8)>>4);
  temp = temp /10;

  return temp;
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up){
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;

  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;

  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;

  long temp = p;
  return temp;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;

  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();

  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT(){
  unsigned int ut;

  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();

  // Wait at least 4.5ms
  delay(5);

  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP(){

  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;

  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();

  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  msb = bmp085Read(0xF6);
  lsb = bmp085Read(0xF7);
  xlsb = bmp085Read(0xF8);

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

  return up;
}

void writeRegister(int deviceAddress, byte address, byte val) {
  Wire.beginTransmission(deviceAddress); // start transmission to device 
  Wire.write(address);       // send register address
  Wire.write(val);         // send value to write
  Wire.endTransmission();     // end transmission
}

int readRegister(int deviceAddress, byte address){

  int v;
  Wire.beginTransmission(deviceAddress);
  Wire.write(address); // register to read
  Wire.endTransmission();

  Wire.requestFrom(deviceAddress, 1); // read a byte

  while(!Wire.available()) {
    // waiting
  }

  v = Wire.read();
  return v;
}

float calcAltitude(float pressure){

  float A = pressure/101325;
  float B = 1/5.25588;
  float C = pow(A,B);
  C = 1 - C;
  C = C /0.0000225577;

  return C;
}


HMC5883L - Digital Compass

A Digital Compass is a simple magnetometer that is used to calculate the strength of magnetic fields and calculate the direction.


Download the Datasheet Here



Connecting the HMC5883L ( connections are for the module above with model number GY-271 for other modules refer to the module datasheet and connect accordingly)
  • Place the HMC5883L Breakout Board on the breadboard
  • Connect the SDA pin on the HMC5883L to the SDA pin on the Induino R3
  • Connect the SCL pin on the HMC5883L to the SCL pin on the Induino R3
  • Conect the Vcc pin on the HMC5883L to 5Volts on the Induino R3
  • Connect the GND pin on the HMC5883L to the GND pin on the Induino R3
Go to File->Examples->HMC5883L-> and click on HMC5883L_raw



Upload the program and watch the various values for pressure in your serial monitor.


Thats It For This Part! Enjoy... and feel free to drop us an email with questions you might have -> info@simplelabs.co.in

 Visit www.simplelabs.co.in for more interesting products

5 comments:

  1. I have mpu-6050 board and ewery test code what i found at net have same proplem,
    ewery row were have mpu or mpu 6050 come error.
    sword mpu error alltime all code what have in netr. what hell must do thats working

    ReplyDelete
  2. hi, I bought a board from HMC5883L rcmodelpart (http://www.rcmodelpart.com/hmc5883l-triple-axis-3axis-compass-magnetometer-sensor-module_p361.html). After connecting the card to the I2C bus arduino (mega 1280) the sensor board is not detected.
    Any suggestions? Is the sensor board broken?

    Thanks.

    ReplyDelete
  3. HI !
    I am getting this error please help me..
    Initializing I2C devices...
    Testing device connections...
    MPU6050 connection failed

    Send any character to begin DMP programming and demo:

    ReplyDelete
  4. after this I am not getting any data like angle or accelerometer.

    ReplyDelete
    Replies
    1. Hey did you get it working? if not drop us an email to info@simplelabs.co.in with your order number

      Delete